TWindowsMediaPlayerでギャップレス再生を行うにはプレイリストを使います。
やり方はとても簡単です。
currentPlaylistにファイルを登録して再生。
それだけです。
var
l_Media: IWMPMedia;
begin
if (OpenDialog1.Execute) then begin
l_Media := IWMPPlayer4(WindowsMediaPlayer1.ControlInterface).newMedia(OpenDialog1.FileName);
WindowsMediaPlayer1.currentPlaylist.appendItem(l_Media);
end;
end;
プレイリストに登録すれば何もせずともギャップレスで連続再生してくれます。
モードを変更すればシャッフル再生もループ再生も行えます。
非常にお手軽です。
そのプレイリストにファイルを登録するにはappendItemメソッドを使います。
このappendItemメソッドは引数としてWideStringやAnsiStringなどのファイル名（文字列）ではなくIWMPMediaオブジェクトを要求します。
なのでファイル名からIWMPMediaオブジェクトをつくる必要があります。
ファイル名からIWMPMediaオブジェクトを得るには二つの方法があります。
一つは「BlueLeaf1336-PROGRAM-2004_0007」にあるようにmediaCollectionオブジェクトのaddメソッドの戻り値として得る方法です。
もう一つはnewMediaメソッドを使う方法です。
上の例では二つ目の方法でやっています。
一つ目のmediaCollection.addを使う方法は再生できないファイルを指定するとエラーが返ります。
エラーチェックをあらかじめやってくれるということで後々楽になります。
ただしちょっと時間がかかります。
またmediaCollectionオブジェクトというのは本家のプレーヤーであるWMP10（9や11とかでも）のライブラリそのものです。
なのでプログラム中からmediaCollectionオブジェクトにファイルを追加したり削除したりすると本家のプレーヤーのライブラリにも影響します。
またflvやdivxなどのファイルはffdshowやflvスプリッターなどをインストールしていてWMPで再生できる環境であってもエラーが返ってきてしまい、このやり方ではIWMPMeidaオブジェクトを取得できません。
flvやdivxファイルなどは、再生できる環境であってもメディアエラーが起きてしまうためです。
メディアエラーが起きてもリトライすることで再生させることは可能なのですがmediaCollectionオブジェクトにそのファイルを追加することはできません。
本来再生できるファイルなのに登録できないというのももったいないことです。
二つ目の方法はエラーチェックなしでIWMPMediaオブジェクトが返るので速いですしflvやdivxなどのファイルもプレイリストに登録可能です。
ただしチェックなしなので再生できないファイルであってもプレイリストに追加できてしまいます。
再生の時にエラーの対処がちょっと面倒になります。
playでも再生はできますがプレイリスト中の特定のメディアを指定することはできません。
で、playItemメソッドは引数にこれまたIWMPMediaオブジェクトを要求します。
var
l_Playlist: IWMPPlaylist;
l_Media: IWMPMedia;
begin
if (OpenDialog1.Execute) then begin
l_Playlist := WindowsMediaPlayer1.currentPlaylist;
l_Media := IWMPPlayer4(WindowsMediaPlayer1.ControlInterface).newMedia(OpenDialog1.FileName);
l_Playlist.appendItem(l_Media);
WindowsMediaPlayer1.control.playItem(l_Playlist.Item[l_Playlist.count -1]); //追加したファイルを再生
end;
end;
ちなみに、
var
l_Media: IWMPMedia;
begin
if (OpenDialog1.Execute) then begin
l_Media := IWMPPlayer4(WindowsMediaPlayer1.ControlInterface).newMedia(OpenDialog1.FileName);
WindowsMediaPlayer1.control.playItem(l_Media);
end;
end;
融通はききません。
flvやdivxファイルなどは先にも書いたように再生できる環境を整えていてもメディアエラーが起きます。
エラーが起きてもリトライすれば二度目からはエラーが起きることもなくちゃんと再生されます。
ただしTWindowsMediaPlayerはリトライせずすぐにプレイリスト中の次のアイテムを再生しようとします。
その結果例えば最初にflvファイルが三つあり、四つ目がwmaファイルだった場合、三つのflvファイルはエラーが起きるので再生されず、四つ目のwmaファイルが最初に再生されることになります。
1.flv、2.flv、3.flvの三つのファイルでエラーが起きます。
結局四つ目のtest.wmaが始めに再生されます。
ただ、エラーが起きた場合WindowsMediaPlayerが自動で（あるいは勝手に）次のアイテムの再生を始めてしまうのでその制御を行わないといけないところがやっかいです。
flvやdivxなどは、一度エラーを起こしてしまえばプレイリストから削除されない限り次からはエラーを起こすことなくちゃんと再生されるようになります。
プレイリストにあるのがflvやdivxばかりのファイルだと次々とエラーが起こり最後までエラーのままで終了し、そのままでは結局再生は始まりません。
手動で再生ボタンを押すかOnPlayStateChangeイベントでNewStateがwmppsReadyになるのを捕まえてcontrols.playItemで再生を始めるようにする必要があります。
でも、せっかくのプレイリストなのでListBoxやComboBoxのリストと同期して表示させたいところです。
var
l_Playlist: IWMPPlaylist;
l_Media: IWMPMedia;
i: Integer;
begin
if (OpenDialog1.Execute) then begin
l_Playlist := WindowsMediaPlayer1.currentPlaylist;
l_Playlist.Clear;
ComboBox1.Items.Clear;
for i := 0 to OpenDialog1.Files.Count -1 do begin
l_Media := IWMPPlayer4(WindowsMediaPlayer1.ControlInterface).newMedia(OpenDialog1.Files[i]);
l_Playlist.appendItem(l_Media);
ComboBox1.Items.Add(l_Media.sourceURL);
end;
WindowsMediaPlayer1.controls.playItem(l_Playlist.Item[0]);
end;
end;
それは手軽にできるのですが、その逆の今再生しているのはプレイリスト中の何番目のメディアかを調べるのは手軽ではありません。
それは現在再生しているメディアがプレイリスト中の何番目に位置するのかを表す、ListBoxやComboBoxでいうところのItemIndexに相当するプロパティやメソッドがないからです。
結局プレイリスト中のインデックスを知るにはメディアオブジェクトのIsIdenticalメソッドを使ってcurrentPlaylist中のアイテムと照合して判断するしかありません。
var
i: Integer;
begin
if (NewState = wmppsPlaying) then begin
for i := 0 to WindowsMediaPlayer1.currentPlaylist.count -1 do begin
if (WindowsMediaPlayer1.currentMedia.isIdentical[WindowsMediaPlayer1.currentPlaylist.Item[i]]) then begin
ComboBox1.ItemIndex := i;
Break;
end;
end;
end;
end;
ビデオファイルは若干間が空きます。
またビデオファイルが続く場合、最初のビデオファイルはハードウェアオーバーレイを使えますが、それに続くビデオファイルはオーバーレイを使えません。
これは始めのビデオが終わりに近づいた時点（だけどまだ再生途中）で次のビデオファイルを開いて待機させるような動作になっているためです。
次のビデオを開いた時点では始めのビデオがハードウェアオーバーレイを使っているので次のビデオはハードウェアオーバーレイを使うことができないということです。
それで困ることといえば映像が乱れてしまうことがあることでしょうか。
ハードウェアオーバーレイを使えなかった場合。
このようにビデオウィンドウに他のウィンドウが重なると映像が乱れることがあります。
WMPのメニューで「ツール」→「オプション」と進みます。
「パフォーマンス」タブの「ビデオ アクセラレータ」グループにある「詳細」ボタンを押します。
「ビデオ アクセラレータ」グループの上の項目の「ビデオ ミキシング レンダラを使う」で「高画質モードを使う」にチェックを入れます。
「オーバーレイを使う」のチェックは外します。
ただこの方法にも弊害があって、それはCPUの使用率が上がってしまうことです。
CPUに余裕があればどうということもないのでしょうが非力なCPUの場合はつらいところです。
最近のPCではハードウェアオーバーレイが複数使えるようです。
2009年に買ったネットブックでは同時に二つのハードウェアオーバーレイが使えています。