Delphi 6 ローテクTips/二重起動防止+ウィンドウを前面に+先に起動したプログラムへ引数を渡す

というものになります。

ウィンドウテキスト（FormのCaptionプロパティ）を変更してしまうのでメインフォームではなく通信専用のフォームを作っておくのがよいと思います。
他のコンポーネント（TEditやTButtonなど）はフォームと違いクラス名はNameプロパティの値にかかわらずTEditやTButtonのままです。
フォームを通信のレシーバーとして利用しているのはそのためです。

program test;

uses
Windows,
Messages,
Forms,
Unit1 in 'Unit1.pas' {Form1},
Unit2 in 'Unit2.pas' {Form_Message};
{$R *.res}

var
lh_Message, lh_Window, lh_Owner: HWND;
begin
//二重起動チェック
if (CreateMutex(nil, False, 'Dsapbi203dap') <> 0) //関数が成功して
and (GetLastError = ERROR_ALREADY_EXISTS) //既に同名のミューテックスオブジェクトがあれば
then begin //二重起動である
lh_Message := FindWindow('TForm_Message', nil); //第二引数はnil
if (ParamCount > 0) and (lh_Message <> 0) then begin
//先に起動しているプログラムに引数を渡す
SendMessage(lh_Message, WM_SETTEXT, 0, LPARAM(CmdLine));
end else begin
//まずメッセージを出す
Application.MessageBox('二重起動は許可されていません', 'メッセージ');

//先に起動しているこのプログラムのウィンドウハンドルとオーナーウィンドウのハンドルを取得
lh_Window := FindWindow('TForm1', nil);
lh_Owner := GetWindow(lh_Window, GW_OWNER);
if (IsIconic(lh_Owner)) then begin
//最小化されていたら元のサイズに戻す
SendMessage(lh_Owner, WM_SYSCOMMAND, WPARAM(SC_RESTORE and $FFF0), 0);
end else begin
//前面に移動させる
SetForegroundWindow(lh_Window);
end;
end;
Exit; //プロラム終了
end;

Application.Initialize;
Application.CreateForm(TForm1, Form1);
Application.CreateForm(TForm_Message, Form_Message);
Application.Run;
end.

unit Unit2;

interface

uses
Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
Dialogs, StdCtrls;

type
TForm_Message = class(TForm)
private
{ Private 宣言 }
procedure WMSetText(var Msg: TMessage); message WM_SETTEXT; //メッセージの受信
public
{ Public 宣言 }
end;

var
Form_Message: TForm_Message;

implementation

{$R *.dfm}

//後から起動したこのプログラムからのメッセージを受けとる
procedure TForm_Message.WMSetText(var Msg: TMessage);
begin
inherited;
{ここに処理内容を記述}

//とりあえずビープを鳴らして表示。
//タイトルバーのテキストが変わっていることを確認
Beep;
Show;
end;

end.